Scarica FORMULE EXCEL NOTE PRATICHE e più Dispense in PDF di Matematica solo su Docsity!
ESERCITAZIONE XLS1 - 2° PARTE
>> Osservazione : Slide 4 - Esercitazione XLS1 - Propedeutico E1.01A - Slide 41 XL Macro
L'algoritmo (sequenza di istruzioni umane che risolve un problema) che ci permette di rispondere correttamente con un SI quando la cella C4 è vuota e con un NO altrimenti potrebbe essere il seguente: "Se la cella C4 è vuota allora rispondo con un SI altrimenti con un NO ". La codifica in EXCEL di tale algoritmo diventa:
=SE(C4="";"SI";"NO")
>> Osservazione : Slide 4 - Esercitazione XLS1 - Propedeutico E1.01A, E1.01B, E1.01C - Slide 41 XL3 Macro
La formula
=CELLA("Tipo";A1)
restituisce una delle seguenti costanti testuali a seconda del contenuto di A.
"b" "l" "v"
La formula
=(CELLA("Tipo";A1)="b")
restituisce VERO se la cella A1 è vuota, FALSO altrimenti. Quindi il suo risultato è una delle 2 costanti booleane:
VERO FALSO
E' pertanto un esempio di condizione.
>> Osservazione 1 :
La condizione " La cella A1 è vuota (ovvero non contiene assolutamente nulla!)?" in EXCEL diventa
=(CELLA("Tipo";A1)="b")
La condizione " La cella A1 appare vuota (quindi oltre ad essere vuota può contenere una
funzione che restituisce la stringa nulla "" come ad esempio ="")?" in EXCEL diventa
=A1=""
La formula appena indicata restituisce VERO anche se la cella è vuota poichè nei confronti
lessicografici EXCEL tratta le celle vuote come se contenessero la stringa nulla "".
Precisazioni - Slide 5 - Esercitazione XLS1 - Propedeutico E1.01D
>> Osservazione 2 :
La condizione " La cella A1 contiene zero ?" in EXCEL diventa
=(A1=0)
Purtroppo la formula appena indicata restituisce VERO anche se la cella è vuota poichè nei
confronti numerici EXCEL tratta le celle vuote come se contenessero uno 0.
>> Osservazione 3 :
In Excel la condizione
=(A1="0")
restituisce FALSO quando nella cella A1 digito 0. Questo perché Excel tende ad
interpretare un input composto da cifre come un numero e non una stringa. Per ottenere
VERO devo digitare in A1 '.
Quindi per EXCEL la seguente relazione
=(1234="1234") restituisce FALSO.
poichè Excel negli operatori di relazione non effettua la conversione da stringa a numero. Nel caso di operatori algebrici invece EXCEL, laddove possibile, converte le stringhe fatte di sole cifre in numeri ovvero:
=1234+"1234" restituisce 2468.
="1234"+"1234" restituisce 2468.
>> Osservazione 4 :
La condizione " La cella A1 appare vuota ma in realtà non lo è ?" in EXCEL diventa
=E(A1="";CELLA("Tipo";A1)="l")
Essendo:
=A1="" equivalente al predicato "La cella A1 appare vuota".
Unendo le 2 condizioni con OPPURE O() ottengo la condizione composta " La cella A
contiene esattamente uno zero ( non importa se numerico o testuale )? che in EXCEL diventa
=O(E(CELLA("Tipo";C4)="v";C4=0);E(C4="0";CELLA("Tipo"
;C4)="l"))
o più semplicemente:
=O(E(CELLA("Tipo";C4)="v";C4=0);C4="0")
Anche la seguente condizione è equivalente:
=E(CELLA("Tipo";C4)<>"b";O(C4=0;C4="0"))
Infatti l'algoritmo (sequenza di istruzioni umane che risolve un problema) che ci permette di rispondere correttamente con un SI quando la cella C4 contiene zero (numerico o testuale) è: "Se la cella C4 non è vuota ED ANCHE C4 è uguale a 0 OPPURE C4 è uguale a "0" allora rispondo con un SI altrimenti con un NO ".
>> Osservazione : Slide 5 - Esercitazione XLS1 - Propedeutico E1.01E
La seguente condizione
=( C4=TRONCA(C4) )
corrisponde alla condizione "La cella C4 è un numero intero?"
>> Osservazione :
Supponiamo che la cella A1 contenga una formula di tipo booleano. Consideriamo la
seguente condizione:
(A1=VERO) ==> attenzione l' = in una condizione va inteso come operatore di confronto
e non di assegnamento!
Si osservi che quando A1 restituisce VERO anche la condizione (A1=VERO) restituisce
lo stesso risultato. Non solo, quando A1 restituisce FALSO anche ( A1=VERO )
restituisce FALSO. Ne consegue che la condizione (A1=VERO) sia equivalente a A
e quindi la prima formula può essere semplificata scrivendo semplicemente la seconda: A.
Analogamente la condizione A1=FALSO può essere semplificata scrivendo NON(A1)
Partendo dalle considerazioni fatte segue:
=SE(Condizione=VERO;...)
può essere così semplificata:
=SE(Condizione;...)
Quindi se supponiamo che nella cella A1 vi sia la formula Eta>=18 segue che la formula
=SE(A1=VERO;"Maggiorenne";"Minorenne")
possa essere riscritta in questo modo
=SE(A1;"Maggiorenne";"Minorenne")
Note per lo studente :
● Tutte le annotazioni presenti in questo documento, ad eccezione di quelle per cui viene segnalato il contrario [ad esempio il testo colorato in grigio], possono essere oggetto di domanda nei test in itinere. ● Gli esercizi propedeutici dell'esercitazione XLS.1 illustrati durante le lezioni vanno analizzati in dettaglio e costituiscono la base dei quesiti presenti nei test in itinere. ● Le funzioni svolte durante la lezione vanno analizzate utilizzando le corrispondenti slide nella sezione "X3 - Macro".
Nota: riprendere dall'esercitazione E1.
LEZIONE 25/03/2026 Mercoledì (13.00-16.30 - 3,5 ore) - C
Precisazioni - Slide 4 - Esercitazione XLS1 - Propedeutico E1.01A
>> Osservazione :
La formula =SE(Condizione;"RispostaA";"RispostaB") corrisponde alla frase " Se la Condizione è vera allora scrivo 'RispostaA' altrimenti 'RispostaB' " e pertanto può essere rappresentata con il seguente diagramma a blocchi:
La funzione =SE() permette di replicare all'interno di un foglio di EXCEL la capacità umana di fare una scelta
>> Osservazione :
Un algoritmo risolutivo potrebbe essere il seguente:
Se il valore di input è maggiore di zero scrivo 'Positivo', Altrimenti Se il valore di input è uguale a 0 scrivo 'Zero' Altrimenti scrivo 'Negativo
Formalizzandolo con un diagramma di flusso ottengo:
Occorre ora convertire l' algoritmo (codificato in un linguaggio naturale oppure formalizzato con un flowchart!) utilizzando le funzioni presenti nel foglio elettronico. Il quesito del nostro esempio, avendo 3 output possibili, richiede 2 funzioni SE().
Risolviamo il quesito per gradi! Partiamo considerando il flowchart che gestisce solo l'output "Positivo"
a cui corrisponde la formula =SE(X>0;"Positivo";"..."). Per indicare che ho lasciato in sospeso l'analisi relativa agli output "Negativo" e "Zero" utilizzo la stringa "..." (si osservi che è racchiusa tra doppi apici!!).
Adesso mi concentro sulla costruzione della formula che dovrà sostituire i "...". Per evitare di dimenticare le parentesi () e i ; parto sostituendo "..." con SE(;;) ottenendo =SE(X>0;"Positivo";SE(;;) ).
Completo questo SE(;;) con i due output rimasti in sospeso: "Positivo" e "Negativo".
Ottengo quindi la soluzione cercata:
=SE(X>0;"Positivo";SE(X=0;"Zero";"Negativo")).
Cambiando la condizione di partenza produco altre soluzioni equivalenti. Eccone alcune:
E(cond1; cond2; ....; cond255) =>restituisce VERO se tutte le condizioni sono vere altrimenti restituisce FALSO ; La funzione E() viene utilizzata per valutare l'appartenenza di un valore X ad un intervallo [a,b] (intervallo interno) ==> =E(X<=b;X>=a). In generale se ho n insiemi I k la cui condizione di appartenenza è C k allora la condizione di appartenenza all' intersezione di tali insiemi è rappresentata dalla condizione E(C 1 ,C 2 ,...,Ck,...,Cn).
NON(cond) => nega l'argomento quindi restituisce VERO se cond è FALSO. Viceversa FALSO se cond è VERO ;
Le formule sottostanti sono tutte equivalenti:
=SE(O(A1<=a;A1>=b);"Esterno a (a,b)";"Appartiene a
(a,b)")
=SE(E(A1>a;A1=b));"Appartiene a (a,b)";"Esterno
a (a,b)")
Osservazioni varie sull'uso della funzione SE()
>> Osservazione 1 :
La formula
=SE(Condizione;VERO;FALSO)
che restituisce VERO quando la Condizione è vera FALSO altrimenti può essere
così semplificata:
=Condizione
>> Osservazione 2 :
Per stabilire l'esito di un esame posso scrivere:
=SE(Esito>=18;"Superato";"Non superato")
I doppi apici indicano che si tratta di una sequenza di caratteri ASCII che va riprodotta esattamente come scritta.
Attenzione: se scrivete gli esiti senza racchiuderli tra " (doppi apici)
=SE(Esito>=18;Superato;Non superato)
verrà visualizzato l'errore #NOME?. Questo perché Excel interpreta le sequenze di caratteri
non racchiuse tra doppi apici come se fossero chiamate a funzioni oppure nomi di celle che abbiamo definito con il bottone " Definisci nome ". Non trovando alcun riscontro di questo tipo Excel mostra l'errore associato a questo genere di situazione.
>> Osservazione 1
Attenzione! La seguente condizione
=E(X>5000;X<20000)
non può essere scritta in EXCEL nel seguente modo:
=E(5000 < X < 20000)
>> Osservazione 2 :
La formula
=E(Condizione1;E(Condizione2;Condizione3))
restituisce VERO se le 3 condizioni risultano vere pertanto può essere semplificata in
questo modo:
=E(Condizione1;Condizione2;Condizione3)
>> Osservazione 3 :
La formula
=(A1=FALSO)
è equivalente a:
=NON(A1)
Osservazioni varie sulle funzioni E(), O() e NON()
Precisazioni
Sia F(X) la funzione che restituisce VERO se X appartiene all'insieme α FALSO
altrimenti. Analogamente sia G(X) la funzione che restituisce VERO se X appartiene
all'insieme β FALSO altrimenti. Allora:
=E(F(X);G(X)) restituisce VERO se X appartiene all'insieme intersezione α∩β
FALSO altrimenti.
=O(F(X);G(X)) restituisce VERO se X appartiene all'insieme unione α ∪ β FALSO
altrimenti.
=E(F(X);NON(G(X))) restituisce VERO se X appartiene all'insieme differenza α-β
FALSO altrimenti.
=O(E(F(X);NON(G(X)));E(NON(F(X));G(X))) restituisce VERO se X
appartiene all'insieme differenza (α-β) ∪ (β-α) FALSO altrimenti. La stessa formula può
essere riscritta: =E(O(F(X);G(X));NON(E(F(X);G(X))))
=NON(F(X)) restituisce VERO se X non appartiene all'insieme α FALSO altrimenti.
=NON(O(F(X);G(X))) restituisce VERO se X non appartiene all'insieme unione
α ∪ β FALSO altrimenti.
Nota per il docente: riprendere dal 1.0.2 dopo aver fatto gli esempi di logica
Esempio 1 - uso funzioni E() , O() ed NON():
Siano P una generica persona, U un corso universitario e R il nome di una regione italiana. Consideriamo le seguenti funzioni booleane che restituiscono VERO se:
d(P) => VERO se P è un dentista m(p) => VERO se P è un maschio c(P) => VERO se P è un appassionato di computer (informatica) i(P) => VERO se P è un cittadino italiano x(P) => VERO se P è un cittadino extra comunitario l(P,U) => VERO se P è un laureando iscritto al corso universitario U r(P,R) => VERO se P è residente nella regione R f(P) => VERO se P ha figli
Sfruttando queste funzioni fornire:
- La condizione che restituisce VERO se P è una dentista appassionata di computer
E( d(P) ; c(P) ; NON( m(P) ) )
- La condizione che restituisce VERO se P è un laureando/a in odontoiatria sardo o siciliano senza figli
E( l(P,"Odontoiatria e Protesi Dentaria") ; O (
r(P,"Sicilia");r(P,"Sardegna") ) ; NON( f(P) ) )
Esempio 2 - uso funzioni E() , O() ed NON():
Sia p una generica persona. Consideriamo le seguenti proposizioni aperte che restituiscono
VERO se:
C(p ) => VERO se " p è affetto da patologia cardiaca"
F(p ) => VERO se " p è affetto da patologia epatica"
G(p ) => VERO se " p è affetto da patologia gastrica".
Fornire la formula in Excel che, combinando opportunamente queste proposizioni con gli
equivalenti operatori logichi E() , O() e NON() restituisce VERO quando il paziente " p è
affetto esattamente da 2 patologie".
Sostanzialmente la formula richiesta dovrà restituire VERO quando la persona p appartiene
ad una delle zone colorate in giallo della figura sottostante.
Seguendo un approccio proposizionale posso affermare: "l'area colorata di giallo corrisponde all'unione delle seguenti regioni ( Z1 , Z2 e Z3 ) ... "
Pertanto potrà essere gestita con una formula del tipo O( Z1(p); Z2(p); Z3(p)
La prima regione Z1 è costituita da quei pazienti affetti contemporaneamente da patologie gastriche e cardiache ma non epatiche ...
... e pertanto la seguente funzione E( C(p); G(p); NON( F(p) ) )
restituisce VERO quando la persona p è affetta dalle patologie che caratterizzano Z.
La seconda regione Z2 è costituita da quei pazienti affetti contemporaneamente da patologie epatiche e cardiache ma non gastriche ...
... e pertanto la seguente funzione E( C(p); F(p); NON( G(p) ) )
restituisce VERO se la persona p è affetta dalle patologie che caratterizzano Z.
L'ultima regione Z3 è costituita da quei pazienti affetti contemporaneamente da patologie epatiche e gastriche ma non cardiache ...
... e pertanto la seguente funzione E( G(p); F(p); NON( C(p) ) )
restituisce VERO se la persona p è affetta dalle patologie che caratterizzano Z.
Quindi una soluzione, piuttosto articolata, diventa:
=O (
Le statistiche indicate nell'immagine non sono richieste nel test d'esame!
Osservazione sulle costanti booleane
In Excel, le costanti booleane VERO e FALSO sono trattate internamente come se fossero
numeri. Alla costante booleana FALSO Excel associa il valore 0 mentre al VERO il valore
1. Qualora delle costanti booleane vengano inserite in una formula che utilizza degli
operatori algebrici ( + , * ,...) Excel le converte automaticamente nei numeri precedentemente
citati e pertanto le sottostanti formule restituiranno i seguenti risultati:
=FALSO*1 restituisce 0.
=VERO*1 restituisce 1.
=FALSO+1 restituisce 1.
=VERO+1 restituisce 2.
=VERO+VERO restituisce 2.
=FALSO+FALSO restituisce 0.
=VERO*100 restituisce 100.
=FALSO*100 restituisce 0.
Le formule booleane E() , O() e NON() possono essere trasformate in modo algebrico
nel seguente modo:
=E(CondizioneA;CondizioneB) ==>
=CondizioneA*CondizioneB
=O(CondizioneA;CondizioneB) ==>
=CondizioneA+CondizioneB-CondizioneA*CondizioneB
=NON(Condizione) ==> =1-Condizione
Nota: completare la conversione delle formule booleane
LEZIONE 02/03/2026 Mercoledì (13.00-16.00 - 3,0 ore) - C
Precisazioni - Slide 14 - Esercitazione XLS1 - Propedeutico E1.04B
>> Osservazione 1:
La formula
=CONTA.VUOTE(Area)
conta le celle che risultano vuote oppure che contengono una formula che restituisce la
stringa vuota (quindi anche quelle che contengono la formula ="" ).
>> Osservazione 2 :
La formula
=CONTA.VALORI(Area)
conta le celle che risultano non vuote ovvero quelle che contengono: un testo, un numero
(quindi anche una data!) oppure una formula (pertanto anche ="" ).
Precisazioni - Slide 16 - Esercitazione XLS1 - Propedeutico E1.04 Variante 1
La funzione CONTA.SE(Area;"Condizione") richiede una stringa come 2°
argomento quando nella condizione appare l'operatore di confronto. Ad esempio:
=CONTA.SE(Area;">18") ==> conto i valori maggiori di 18
=CONTA.SE(Area;"<>0") ==> conto i valori diversi da zero
=CONTA.SE(Area;"=0") ==> conto i valori uguali a zero (potevo anche
scrivere: =CONTA.SE(Area;"0") )
altrimenti non è necessario
=CONTA.SE(Area;0) ==> conto i valori uguali a zero
=CONTA.SE(Area;VERO) ==> conto i valori uguali a VERO
